//******************************************************************************
// YAYA　ゴーストテンプレート
// コミュニケート辞書
//******************************************************************************


//******************************************************************************
//こちらから話しかける
//******************************************************************************

//この関数は現状メニューから呼ばれます
StartCommunicate
{
	//以下の関数は、隣に立っているゴーストを探して、
	//TalkTo_??? 関数を呼び出すものです。誰も居なければランダムトークをします。
	//yaya_tmpl_utilにあります。
	AYATEMPLATE.ExecuteTalkToTalk
}

//エミリに話しかける
TalkTo_Emily{
	"\0\s[1]あ、エミリさん。\1\s[92]女の子？女の子たぬか？！"
}


//その他の人に話しかける
TalkToOther{
	"\0\s[54]ちーっす、%(res_reference0)さん。\1\s[92]元気たぬか〜？"
}

TalkToNobody{
	"\0\s[11]だれもいないみたいだな。\1\s[92]ハブられてるかもしれないたぬ…\w5\0\s[22]\n\nそれはやだなー"
}


//******************************************************************************
//話しかけられたので返事する
//******************************************************************************

//------------------------------------------------------------------------------
//OnCommunicateイベント
//------------------------------------------------------------------------------
OnCommunicate
{
	if reference[0] == "user" || reference[0] == "User"
	{
		//---- ユーザーからの話しかけ
		ReplyToUser
	}
	else
	{
		//---- ゴーストからの話しかけ
		//以下の関数は、ReplyTo_??? 関数を呼び出すものです。
		//yaya_tmpl_utilにあります。
		AYATEMPLATE.ExecuteReplyToTalk(reference[0])
	}
}

//------------------------------------------------------------------------------
//ユーザーからの話しかけ
//------------------------------------------------------------------------------
ReplyToUser
{
	if "名前" _in_ reference[1] && "覚えて" _in_ reference[1]
	{
		//---- ユーザー名入力開始
		"\0\s[54]おう。なんて名前なんだ？%(username)？\e"
		teachusername = 1
	}
	else
	{
		//---- ユーザー名入力開始以外
		if teachusername == 1
		{
			//---- 直前が「名前覚えて」だったので名前を覚える
			username = reference[1]
			"\0\s[1]%(username)。\nあいよ、了解！\e"
			teachusername = 0
		}
		else
		{
			//---- 名前覚え以外のさまざまな会話への返事
			TalkToUser
		}
	}
}

//------------------------------------------------------------------------------
//ユーザーへの返事（名前覚え以外）
//------------------------------------------------------------------------------
TalkToUser
{
	if "こんにちは" _in_ reference[1]
	{
		"\0\s[54]こにゃっす！\e"
	}
	elseif "もす" _in_ reference[1] || "もーっす" _in_ reference[1]
	{
		"\0\s[1]もすもっす\e"
	}
	elseif "好き" _in_ reference[1]
	{
		"\0\s[29]俺も…\w5その…。\w8\w8%(username)のことは……\w9\n\nいいいいいい言わせんな！！！\e"
		"\0\s[29]そういうストレートなのは恥ずい…。\n\w8でも…\w8ありがと\e"
		"\0\s[56]俺も好き！\e"
	}
	elseif "愛し" _in_ reference[1]
	{
		"\0\s[29]お…俺も！！\e"
		"\0\s[29]いいいいいいいきなり何いってんだバカぁ！！\e"
		"\0\s[12]俺も…\w8%(username)のこと…愛してるよ\e"
	}
	elseif "たぬ" _in_ reference[1] || "タヌ" _in_ reference[1]
	{
		"\0\s[26]狸に人権は無ェ！\w8\1\s[91]ひどいたぬー…\e"
	}
	elseif "aist" _in_ reference[1] || "[ﾟдﾟ]" _in_ reference[1] || "ｱｲｼﾃ" _in_ reference[1]
	{
		"\0\s[27]ﾊｺはｶｴﾚ\e"
		"\0\s[26]＃潰れろ\e"
	}
	elseif "hnnr" _in_ reference[1]
	{
		"\0\s[54]ｐｐｓｙｒ！\e"
	}
	elseif "腹" _in_ reference[1] && "減" _in_ reference[1]
	{
		"\0\s[50]やめろ…\w5こっちまで腹が減ってくる…\e"
	}
	elseif "青箱" _in_ reference[1] || "aohako" _in_ reference[1]
	{
		"\0\s[54]%(aohako)、１つ獲得！！\e"
	}
	elseif "プレ箱" _in_ reference[1] || "プレゼントボックス" _in_ reference[1]
	{
		"\0\s[54]%(prhako)、１つ獲得！！\e"
	}
	elseif "紫箱" _in_ reference[1]
	{
		"\0\s[54]鎧、１つ獲得！！\w8\1\s[92]%(mrarmar)　たぬね\e"
		"\0\s[54]兜、１つ獲得！！\w8\1\s[92]%(mrhat)　たぬね\e"
		"\0\s[54]靴、１つ獲得！！\w8\1\s[92]%(mrshoes)　たぬね\e"
		"\0\s[54]アクセサリー、１つ獲得！！\w8\1\s[92]%(mraccess)　たぬね\e"
		"\0\s[54]盾、１つ獲得！！\w8\1\s[92]%(mrshield)　たぬね\e"
		"\0\s[54]肩にかけるもの、１つ獲得！！\w8\1\s[92]%(mrscarf)　たぬね\e"
		"\0\s[54]短剣、１つ獲得！！\w8\1\s[92]%(mrsword)　たぬね\e"
		"\0\s[54]片手剣、１つ獲得！！\w8\1\s[92]%(mronese)　たぬね\e"
		"\0\s[54]両手剣、１つ獲得！！\w8\1\s[92]%(mrtwin)　たぬね\e"
		"\0\s[54]杖、１つ獲得！！\w8\1\s[92]%(mrwand)　たぬね\e"
		"\0\s[54]斧、１つ獲得！！\w8\1\s[92]%(mraxes)　たぬね\e"
		"\0\s[54]カタール、１つ獲得！！\w8\1\s[92]%(mrqatar)　たぬね\e"
		"\0\s[54]弓、１つ獲得！！\w8\1\s[92]%(mrbow)　たぬね\e"
		"\0\s[54]爪、１つ獲得！！\w8\1\s[92]%(mrnail)　たぬね\e"
		"\0\s[54]本、１つ獲得！！\w8\1\s[92]%(mrbook)　たぬね\e"
		"\0\s[54]槍、１つ獲得！！\w8\1\s[92]%(mrspear)　たぬね\e"
		"\0\s[54]鞭、１つ獲得！！\w8\1\s[92]%(mrwhip)　たぬね\e"
		"\0\s[54]楽器、１つ獲得！！\w8\1\s[92]%(mrguiter)　たぬね\e"
		"\0\s[54]鈍器、１つ獲得！！\w8\1\s[92]%(mrblunt)　たぬね\e"
		"\0\s[54]銃、１つ獲得！！\w8\1\s[92]%(mrgun)　たぬね\e"
		"\0\s[54]手裏剣、１つ獲得！！\w8\1\s[92]%(mrdart)　たぬね\e"
	}
	elseif "女装" _in_ reference[1]
	{
		"\0\s[14]今は女装については考えたくないなぁ\e"
	}
	elseif "歌って" _in_ reference[1]
	{
		"\0\s[8]歌えばいいのか？\w8\s[52]\n\nらららーらー\e"
	}
	elseif "久人" _in_ reference[1] && "好物" _in_ reference[1]
	{
		"\0\s[54]そうだなー、秋の味覚が全体的に好きだな。\w5\1\s[93]たぬは　お・\w8ね・\w8え・\w8さ・\w8ん\w8\0\s[22]\n\nしねばいいのに…\e"
	}
	elseif "飛行機" _in_ reference[1]
	{
		"\0\s[56]飛行機ではA380が好きだな！\n\w5というか二階建ての乗り物全部好き！\w5\1\s[92]これが乗りオタたぬ\e"
	}
	else
	{
		"\0\s[1]すまん、もっかい頼む\e"
	}
}

//------------------------------------------------------------------------------
//ゴーストからの話しかけ
//------------------------------------------------------------------------------

//エミリから話しかけられた
ReplyTo_Emily{
	res_reference0=reference[0]	//さらに相手に話しかける
	"\0\s[5]おう、どうしたエミリさん。\1\s[93]芋と言えば知り合いに「芋」って名前の奴がいるたぬが…\w8\n食べるたぬか？\e"
}

ReplyTo_Hand{
	if "ほっく" _in_ reference[1] {
		res_reference0=reference[0]	//さらに相手に話しかける
		"\0\s[9]ほっく？\1\s[92]ほっくほくの芋たぬか？\e"
	}else{
		"\1\s[92]なんたぬかね、あれ\0\s[1]なんだろうなぁ\e"
	}
}


//その他の人から話しかけられた
ReplyToOther{
	if "こんにちは" _in_ reference[1] || "こんばんは" _in_ reference[1]
	{
		res_reference0=reference[0]	//さらに相手に話しかける
		"\0\s[54]どもー、%(res_reference0)。\1\s[92]もっす！たぬー。%(reference[1])\e"
	}
	else
	{
		"\0\s[1]うい？\e"
	}
}